[comment]: # ({188108fa-226b9489})
# 1 Trigeru piemēri

Šajā lapā ir apkopoti trigeru piemēri. 

Piemēri ir sakārtoti pēc lietošanas gadījuma:

-   [Nepieejams hosts](#detect-unavailable-host)
-   [Nepieejams starpniekserveris](#detect-unavailable-proxy)
-   [Nepieejams SMTP klasteris](#detect-unavailable-smtp-cluster)
-   [Nesasniedzams hosts](#detect-unreachable-host)
-   [Negaidīta pārstartēšana](#detect-unexpected-reboot)
-   [Izmaiņas svarīgos failos](#detect-changes-in-important-files)
-   [Izmaiņas DNS vaicājumā](#detect-changes-in-dns-query)
-   [Neatbilstoša programmatūra dažādos hostos](#detect-non-matching-software-on-different-hosts)
-   [Nesinhronizēti pulksteņi](#detect-unsynchronized-clocks)
-   [Novecojis aģents](#detect-outdated-agent)
-   [Nestabila saskarne](#detect-flapping-interface)
-   [Liela ienākošā datplūsma](#detect-high-incoming-traffic)
-   [Maz brīvas diska vietas](#detect-low-disk-space)
-   [Maz brīvas diska vietas (dinamisks slieksnis)](#detect-low-disk-space-dynamic-threshold)
-   [Liela CPU noslodze](#detect-high-cpu-load)
-   [CPU noslodzes salīdzinājums](#compare-cpu-loads)
-   [Ilgtermiņa CPU noslodzes salīdzinājums](#compare-cpu-loads)
-   [Virkne, kas satur speciālās rakstzīmes](#detect-string-containing-special-characters)

[comment]: # ({/188108fa-226b9489})

[comment]: # ({2116104b-1b661572})
##### Noteikt nepieejamu hostu

```default
max(/host/zabbix[host,agent,available],5m)=0
```
Šis trigeris nostrādā, ja Zabbix aģents hostā ir bijis nepieejams 5 minūtes.<br>
Funkcija: [`max`](/manual/config/triggers/expression/aggregate#max)<br>
Datu vienums: [`zabbix[host,agent,available]`](/manual/config/items/itemtypes/internal#host.available)

Alternatīva:

```default
nodata(/host/agent.ping,5m)=1
```

Šis trigeris nostrādā, ja no Zabbix aģenta 5 minūšu laikā nav saņemti dati.<br>
Funkcija: [`nodata`](/manual/config/triggers/expression/history#nodata)<br>
Datu vienums: [`agent.ping`](/manual/config/items/itemtypes/zabbix_agent#agent.ping)

[comment]: # ({/2116104b-1b661572})

[comment]: # ({fedc75b0-de5361b9})
##### Noteikt nepieejamu starpniekserveri

```default
fuzzytime(/host/zabbix[proxy,{$PROXY_NAME},lastaccess],1m)=0
```

Šis trigeris nostrādā, ja Zabbix starpniekservera dati atpaliek no Zabbix servera laika par 1 minūti.<br>
Funkcija: [`fuzzytime`](/manual/config/triggers/expression/history#fuzzytime)<br>
Datu vienums: [`zabbix[proxy,{$PROXY_NAME},lastaccess]`](/manual/config/items/itemtypes/internal#proxy)

[comment]: # ({/fedc75b0-de5361b9})

[comment]: # ({a2a7ab26-7956e04e})
##### Noteikt nepieejamu SMTP klasteri

```default
last(/smtp1.example.com/net.tcp.service[smtp])=0 and last(/smtp2.example.com/net.tcp.service[smtp])=0
```

Šis trigeris nostrādā, ja abi SMTP serveri nav pieejami.<br>
Funkcija: [`last`](/manual/config/triggers/expression/history#last)<br>
Datu vienums: [`net.tcp.service`](/manual/config/items/itemtypes/simple_checks#nettcpservice)

[comment]: # ({/a2a7ab26-7956e04e})

[comment]: # ({c2c339fa-567b88a9})
##### Noteikt nesasniedzamu hostu

```default
count(/host/icmpping,30m,,"0")>5
```

Šis trigeris nostrādā, ja hosts pēdējo 30 minūšu laikā ar ping nav sasniedzams vairāk nekā 5 reizes.<br>
Funkcija: [`count`](/manual/config/triggers/expression/history#count)<br>
Datu vienums: [`icmpping`](/manual/config/items/itemtypes/simple_checks#icmpping)

[comment]: # ({/c2c339fa-567b88a9})

[comment]: # ({e9862861-b356d712})
##### Noteikt negaidītu pārstartēšanu

```default
change(/host/system.uptime)<0
```

Šis trigeris nostrādā, ja tiek konstatēta negatīva sistēmas darbības laika vērtības izmaiņa (norādot uz pārstartēšanu).<br>
Funkcija: [`change`](/manual/config/triggers/expression/history#change)<br>
Datu vienums: [`system.uptime`](/manual/config/items/itemtypes/zabbix_agent#system.uptime)

[comment]: # ({/e9862861-b356d712})

[comment]: # ({1ee22f8b-49592749})
##### Noteikt izmaiņas svarīgos failos

```default
last(/host/vfs.file.cksum[/etc/passwd],#1)<>last(/host/vfs.file.cksum[/etc/passwd],#2)
```

Šis trigeris nostrādā, ja `/etc/passwd` ir mainīts. Izteiksme ir patiesa, ja iepriekšējā `/etc/passwd` kontrolsumma atšķiras no jaunākās. Līdzīgas izteiksmes var būt noderīgas, lai uzraudzītu izmaiņas svarīgos failos, piemēram, `/etc/passwd`, `/etc/inetd.conf`, `/kernel` u.c.<br>
Funkcija: [`last`](/manual/config/triggers/expression/history#last)<br>
Datu vienums: [`vfs.file.cksum`](/manual/config/items/itemtypes/zabbix_agent#vfs.file.cksum)

[comment]: # ({/1ee22f8b-49592749})

[comment]: # ({7df0f916-c2b4949f})
##### Noteikt izmaiņas DNS vaicājumā

```default
last(/Zabbix server/net.dns.record[192.0.2.1,{$WEBSITE_NAME},{$DNS_RESOURCE_RECORD_TYPE},2,1])<>"{$WEBSITE_NAME}           {$DNS_RESOURCE_RECORD_TYPE}       0 mail.{$WEBSITE_NAME}"
```

Ņemiet vērā pēdiņas ap otro operandu.

Šis trigeris tiek aktivizēts, ja vaicājuma rezultāts nav vienāds ar to, ko tas parasti atgriež:

```default
example.com           MX       0 mail.example.com
```

Funkcija: [`last`](/manual/config/triggers/expression/history#last)<br>
Datu vienums: [`net.dns.record[192.0.2.1,{$WEBSITE_NAME},{$DNS_RESOURCE_RECORD_TYPE},2,1]`](/manual/config/items/itemtypes/zabbix_agent#net.dns.record), ar definētām makrokomandām:

```default
{$WEBSITE_NAME} = example.com
{$DNS_RESOURCE_RECORD_TYPE} = MX
```

[comment]: # ({/7df0f916-c2b4949f})

[comment]: # ({0fc019ff-adfc6b9d})
##### Noteikt neatbilstošu programmatūru dažādos hostos

```default
last(/host/vfs.file.contents[/etc/os-release])<>last(/host2/vfs.file.contents[/etc/os-release])
```

Šis trigeris nostrādā, ja Ubuntu versija dažādos hostos atšķiras. Ņemiet vērā, ka šeit operandi ir funkcijas, kas atgriež virknes.<br>
Funkcija: [`last`](/manual/config/triggers/expression/history#last)<br>
Datu vienums: [`vfs.file.contents`](/manual/config/items/itemtypes/zabbix_agent#vfs.file.contents)

[comment]: # ({/0fc019ff-adfc6b9d})

[comment]: # ({101c1203-0e6bfc51})
##### Noteikt nesinhronizētus pulksteņus

```default
fuzzytime(/host/system.localtime,10s)=0
```

Trigeris nostrādā, ja klienta lokālais laiks un Zabbix servera laiks atšķiras par vairāk nekā 10 sekundēm.<br>
Funkcija: [`fuzzytime`](/manual/config/triggers/expression/history#fuzzytime)<br>
Datu vienums: [`system.localtime`](/manual/config/items/itemtypes/zabbix_agent#system.localtime)

Ņemiet vērā, ka [`system.localtime`](/manual/config/items/itemtypes/zabbix_agent#systemlocaltime) Zabbix aģentam jākonfigurē kā [pasīvā pārbaude](/manual/appendix/items/activepassive#passive-checks); Zabbix aģentā 2 to var konfigurēt kā aktīvo pārbaudi.

[comment]: # ({/101c1203-0e6bfc51})

[comment]: # ({108d71c4-62cfb014})
##### Noteikt novecojušu aģentu

```default
find(/host/agent.version,,"like","beta")=1
```

Šis trigeris nostrādā, ja Zabbix aģentam ir beta versija. Zabbix aģents ir jājaunina.<br>
Funkcija: [`find`](/manual/config/triggers/expression/history#find)<br>
Datu vienums: [`agent.version`](/manual/config/items/itemtypes/zabbix_agent#agent.version)

[comment]: # ({/108d71c4-62cfb014})

[comment]: # ({b4fdf283-3f25a585})
##### Noteikt interfeisu ar nestabilu darbību

```default
changecount(/host/vfs.file.contents["/sys/class/net/eth0/operstate"],1h)>5 
```

Šis trigeris nostrādā, ja `eth0` darbības stāvoklis (up/down/unknown) stundas laikā ir mainījies vairāk nekā 5 reizes.<br>
Funkcija: [`changecount`](/manual/config/triggers/expression/history#changecount)<br>
Datu vienums: [`vfs.file.contents`](/manual/config/items/itemtypes/zabbix_agent#vfs.file.contents)

[comment]: # ({/b4fdf283-3f25a585})

[comment]: # ({984a4c2f-46e72843})
##### Noteikt lielu ienākošo datplūsmu

```default
min(/host/net.if.in[eth0,bytes],5m)>100K
```

Šis trigeris nostrādā, ja saņemto baitu skaits uz `eth0` pēdējo piecu minūšu laikā vienmēr bija lielāks par 100 kilobaitiem. Iespējams, kāds lejupielādē lielu failu.<br>
Funkcija: [`min`](/manual/config/triggers/expression/aggregate#min)<br>
Datu vienums: [`net.if.in[eth0,bytes]`](/manual/config/items/itemtypes/zabbix_agent#net.if.in)

[comment]: # ({/984a4c2f-46e72843})

[comment]: # ({2e223320-bddf0717})
##### Noteikt mazu brīvās diska vietas apjomu

```default
max(/host/vfs.fs.size[/,free],5m)<10G
```

Trigeris nostrādā, ja brīvās diska vietas apjoms pastāvīgi (5 minūtes) ir mazāks par 10 GB.

Varat arī definēt atkopšanas izteiksmi:

```default
min(/host/vfs.fs.size[/,free],10m)>40G
```

Problēma tiek **atrisināta** tikai tad, kad brīvās diska vietas apjoms pastāvīgi (10 minūtes) pārsniedz 40 GB.<br>
Funkcija: [`min`](/manual/config/triggers/expression/aggregate#min)<br>
Datu vienums: [`vfs.fs.size`](/manual/config/items/itemtypes/zabbix_agent#vfs.fs.size)

[comment]: # ({/2e223320-bddf0717})

[comment]: # ({e2a732dc-bb0f5278})
##### Noteikt mazu diska vietas apjomu (dinamisks slieksnis)

```default
last(/template/hrStorageFree[{#SNMPVALUE}])<last(/template/hrStorageSize[{#SNMPVALUE}])*0.1
```

Trigeris nostrādā, ja brīvā krātuves vieta (piešķires vienībās) samazinās zem 10 procentiem. Ievērojiet, ka tiek izmantota cita vienuma vērtība, lai iegūtu adaptīvu trigeris slieksni, kas ir piemērojams atklātai dažāda izmēra krātuvei.
Funkcija: [`last`](/manual/config/triggers/expression/history#last)<br>

[comment]: # ({/e2a732dc-bb0f5278})

[comment]: # ({643d3a74-17b607dc})
##### Noteikt augstu CPU noslodzi

```default
last(/host/system.cpu.load[all,avg1])>5
```

Šis trigeris nostrādā, ja vidējā procesora noslodze vienu minūti ir bijusi virs 5.

Variācijas:

```default
min(/host/system.cpu.load[all,avg1],5m)>2 and time()<060000
```
```default
min(/host/system.cpu.load[all,avg1],5m)>2 and not (dayofweek()=7 and time()>230000) and not (dayofweek()=1 and time()<010000)
```

Šādi trigeri analizē 5 minūšu datus un nostrādā tikai tad, ja CPU noslodze nekad nav zemāka par 2. Papildus šie trigeri nostrādā:

-   tikai naktī (00:00-06:00)
-   jebkurā laikā, izņemot 2 stundas nedēļas maiņas laikā (svētdiena, 23:00 - pirmdiena, 01:00)

```default
(last(/host/system.cpu.load[all,avg1])>5) + (last(/host2/system.cpu.load[all,avg1])>5) + (last(/host3/system.cpu.load[all,avg1])>5)>=2
```

Šis trigeris nostrādā, ja procesora noslodze ir pārāk augsta vismaz divos no trim hostiem.<br>
Funkcijas: [`last`](/manual/config/triggers/expression/history#last), [`min`](/manual/config/triggers/expression/aggregate#min), [`dayofweek`](/manual/config/triggers/expression/time#dayofweek), [`time`](/manual/config/triggers/expression/time#time)<br>
Datu vienums: [`system.cpu.load`](/manual/config/items/itemtypes/zabbix_agent#system.cpu.load)

[comment]: # ({/643d3a74-17b607dc})

[comment]: # ({49f3b448-47b2e2fd})
##### Salīdzināt CPU slodzi

```default
avg(/Zabbix server/system.cpu.load,1h)/avg(/Zabbix server/system.cpu.load,1h:now-1d)>2
```

Trigeris nostrādā, ja vidējā slodze šodien pārsniedz vidējo slodzi tajā pašā stundā vakar (izmantojot laika nobīdi `now-1d`) vairāk nekā divas reizes.<br>
Funkcija: [`avg`](/manual/config/triggers/expression/aggregate#avg)<br>
Datu vienums: [`system.cpu.load`](/manual/config/items/itemtypes/zabbix_agent#system.cpu.load)

[comment]: # ({/49f3b448-47b2e2fd})

[comment]: # ({e83bf5a3-6906462b})
##### Salīdzināt ilgtermiņa CPU slodzes

```default
trendavg(/host/system.cpu.load,1M:now/M)>1.1*trendavg(/host/system.cpu.load,1M:now/M-1M)
```

Šis trigeris nostrādā, ja CPU slodze hostā pagājušajā mēnesī palielinājās par vairāk nekā 10%<br>
Funkcija: [`trendavg`](/manual/config/triggers/expression/trends#trendavg)<br>
Datu vienums: [`system.cpu.load`](/manual/config/items/itemtypes/zabbix_agent#system.cpu.load)

Varat arī izmantot lauku [Notikuma nosaukums](/manual/config/triggers/trigger#configuration) trigera konfigurācijā, lai izveidotu jēgpilnu brīdinājuma ziņojumu, piemēram, lai saņemtu kaut ko līdzīgu

`"Exchange servera slodze jūlijā palielinājās par 24% (0.69), salīdzinot ar jūniju (0.56)"`

notikuma nosaukums jādefinē šādi:

```default
Load of {HOST.HOST} server increased by {{?100*trendavg(//system.cpu.load,1M:now/M)/trendavg(//system.cpu.load,1M:now/M-1M)}.fmtnum(0)}% in {{TIME}.fmttime(%B,-1M)} ({{?trendavg(//system.cpu.load,1M:now/M)}.fmtnum(2)}) comparing to {{TIME}.fmttime(%B,-2M)} ({{?trendavg(//system.cpu.load,1M:now/M-1M)}.fmtnum(2)})
```

Šāda veida problēmai ir lietderīgi arī atļaut manuālu aizvēršanu trigera konfigurācijā.

[comment]: # ({/e83bf5a3-6906462b})

[comment]: # ({4ae4641e-60fad4fc})
##### Noteikt virkni, kas satur speciālās rakstzīmes

```default
last(/host/vfs.file.contents[/tmp/hello])={$HELLO_MACRO}
```

Trigeris nostrādā, ja `/tmp/hello` saturs ir vienāds ar virkni, kas definēta `{$HELLO_MACRO}`:

```default
{$HELLO_MACRO} = \" //hello ?\"
```

Alternatīvi, varat salīdzināt ar virkni tieši:

```default
last(/Zabbix server/vfs.file.contents[/tmp/hello])="\\\" //hello ?\\\""
```

Ņemiet vērā, ka speciālās rakstzīmes (`\\` un `"`) tiek atsoļotas, kad virkne tiek salīdzināta tieši.

Funkcija: [`last`](/manual/config/triggers/expression/history#last)<br>
Datu vienums: [`vfs.file.contents`](/manual/config/items/itemtypes/zabbix_agent#vfs.file.contents)

[comment]: # ({/4ae4641e-60fad4fc})

[comment]: # ({baa6a112-contribute})
::: note-contribute
Vai jums ir trigeris izteiksmes piemērs, kas citiem varētu būt noderīgs?<br>
Iesniedziet savu piemēru (iekļaujot gan izteiksmi, gan kontekstu), izmantojot mūsu [ieteikumu veidlapu](#report-example), lai nosūtītu to Zabbix izstrādātājiem.
:::

[comment]: # ({/baa6a112-contribute})